全球主机交流论坛

标题: cmd批处理脚本，一键挂载/分离/格式化/创建，VHD虚拟硬盘 [打印本页]
作者: 碧莲    时间: 2019-9-2 13:14
标题: cmd批处理脚本，一键挂载/分离/格式化/创建，VHD虚拟硬盘
本帖最后由 碧莲 于 2019-9-2 13:18 编辑

制作DD包专用脚本，简略你所有繁琐的操作。




  2. @echo off
  3. >nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
  4. if '%errorlevel%' NEQ '0' (
  5. goto UACPrompt
  6. ) else ( goto gotAdmin )
  7. :UACPrompt
  8. echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
  9. echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
  10. "%temp%\getadmin.vbs"
  11. exit /B
  12. :gotAdmin
  13. if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
  14. if exist %tmp%\vhdconf (del /f /q %tmp%\vhdconf)
  15. title www.nat.ee
  16. mode con: cols=45 lines=10
  17. color 2F
  18. pushd "%~dp0"
  19. for /f "delims=" %%i in ('dir /b %~dp0^|findstr ".*\.vhd"') do (set name=%%i)
  20. :menu
  21. cls
  22. echo.
  23. echo 1.挂载 %name%
  24. echo.
  25. echo 2.分离 %name%
  26. echo.
  27. echo 3.创建 VHD
  28. echo.
  29. echo 4.格式化 %name%
  30. echo.
  31. choice /C:1234 /N /M "请输入你的选择[1,2,3,4]"：
  32. if errorlevel 4 goto:vhdformat
  33. if errorlevel 3 goto:vhdadd
  34. if errorlevel 2 goto:vhdoff
  35. if errorlevel 1 goto:vhdon
  36. :vhdon
  37. echo SELECT VDISK FILE= "%~dp0%name%" >%tmp%\vhdconf
  38. echo ATTACH VDISK NOERR >>%tmp%\vhdconf
  39. echo LIST DISK >>%tmp%\vhdconf
  40. DISKPART /s %tmp%\vhdconf > nul
  41. exit
  42. :vhdoff
  43. echo SELECT VDISK FILE= "%~dp0%name%" >%tmp%\vhdconf
  44. echo ATTACH VDISK NOERR >>%tmp%\vhdconf
  45. echo DETACH VDISK >>%tmp%\vhdconf
  46. echo LIST DISK >>%tmp%\vhdconf
  47. DISKPART /s %tmp%\vhdconf > nul
  48. exit
  49. :vhdadd
  50. cls
  51. echo.
  52. echo 自定义vhd虚拟硬盘文件名称与大小,按回车
  53. echo.
  54. set /p newname=文件名：
  55. echo.
  56. set /p value=大小(G):
  57. set /a mx = (value)*(1024)
  58. echo CREATE VDISK FILE="%~dp0%newname%.vhd" TYPE=FIXED MAXIMUM=%mx% >>%tmp%\vhdconf
  59. echo SELECT VDISK FILE="%~dp0%newname%.vhd" >>%tmp%\vhdconf
  60. echo ATTACH VDISK NOERR >>%tmp%\vhdconf
  61. echo CLEAN >>%tmp%\vhdconf
  62. echo CREATE PARTITION PRIMARY >>%tmp%\vhdconf
  63. echo FORMAT FS=NTFS QUICK >>%tmp%\vhdconf
  64. echo ASSIGN >>%tmp%\vhdconf
  65. DISKPART /s %tmp%\vhdconf > nul
  66. exit
  67. :vhdformat
  68. echo SELECT VDISK FILE="%~dp0%name%" >>%tmp%\vhdconf
  69. echo ATTACH VDISK NOERR >>%tmp%\vhdconf
  70. echo CLEAN >>%tmp%\vhdconf
  71. echo CREATE PARTITION PRIMARY >>%tmp%\vhdconf
  72. echo FORMAT FS=NTFS QUICK >>%tmp%\vhdconf
  73. echo ASSIGN >>%tmp%\vhdconf
  74. DISKPART /s %tmp%\vhdconf > nul
  75. exit
复制代码

将此代码保存为.bat 即可。
当前脚本目录下，只能存在一个vhd文件。

原创首发，转载请注明此帖子链接！
荣耀&制作
作者: yuchongwei    时间: 2019-9-2 20:18
技术活要顶顶
作者: 365edu    时间: 2019-9-2 20:20
收藏帮顶
作者: h3cie    时间: 2019-9-2 20:21
技术活要顶顶
作者: vanechka    时间: 2019-9-2 20:30
日，这个不顶天理难容
作者: Stay    时间: 2019-9-2 22:14
已经快要放弃了，ikoula 家的独服DD包太难做了，全部DD不成功



欢迎光临 全球主机交流论坛 (https://loc.mjj8.eu.org/) Powered by Discuz! X3.4